chicken-box/flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs.systems.follows = "systems";
    };
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    ### De-dupe flake dependencies
    systems.url = "github:nix-systems/default";
  };

  outputs =
    inputs:
    inputs.flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = inputs.nixpkgs.legacyPackages.${system};
        treefmtEval = inputs.treefmt-nix.lib.evalModule pkgs ./treefmt.nix;
      in
      {
        ### nix {run,shell,build}
        packages = {
          default = pkgs.callPackage ./package.nix { };
        };

        ### nix fmt
        formatter = treefmtEval.config.build.wrapper;

        ### nix flake check
        checks.formatting = treefmtEval.config.build.check inputs.self;

        ### nix develop
        devShells.default = pkgs.mkShell {
          nativeBuildInputs =
            with pkgs;
            [
              nodePackages.prettier
              typescript-language-server

              nodejs
              pnpm

              cargo
              openssl
              pango
              pkg-config
              rustc
              webkitgtk_4_1
            ]
            ++ (with gst_all_1; [
              gst-libav
              gst-plugins-bad
              gst-plugins-base
              gst-plugins-good
              gst-plugins-ugly
              gstreamer
            ]);

        };
      }
    );
}